StickyButton Class for AS 3.0

There are very many ways you can use or adopt this class. Here is one of the simplest ways by specifying MovieClip base class in Library:
Download example (Flash CS3 .FLA file)

 
package {
 
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	/**
	 * @author - darklow, First Intelligence www.first.lv (rewriting from AS 1.0 to AS 3.0)
	 * @author - www.mjau-mjau.vom (original AS 1.0 code author)
	 */
 
	public class StickyButton extends MovieClip	{
 
		private var accel:Number = .6;
		private var convert:Number = .7;
		private var r:Number = 3;
 
		private var xstart:Number;
		private var ystart:Number;
 
		private var targetx:Number;
		private var targety:Number;
		private var t:Number;
 
		private var xpos:Number = 0;
		private var ypos:Number = 0;
		private var drag:Number = 0;
		private var drag_this:Boolean = false;
		private var mouseOnStage:Boolean = false;
 
		public function StickyButton() {
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
		private function init(e:Event = null):void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			var iterations:Number = 5;
			xstart = x;
			ystart = y;
			targetx = xstart;
			targety = ystart;
			var xx:Number = (2 * Math.PI) * (1 / iterations);
			t = Math.tan(xx);
			addEventListener(Event.ENTER_FRAME, checkFrame);
			stage.addEventListener(MouseEvent.MOUSE_MOVE, function(event:MouseEvent):void {
				mouseOnStage = true;
			});
			stage.addEventListener(Event.MOUSE_LEAVE, function(event:Event):void {
				mouseOnStage = false;
			});
		}
		private function checkFrame(e:Event):void {
			if (this.hitTestPoint(root.mouseX, root.mouseY, true) && mouseOnStage) {
				var deltax:Number = parent.mouseX - xstart;
				var deltay:Number = parent.mouseY - ystart;
				targetx = (parent.mouseX - deltax / r);
				targety = (parent.mouseY - deltay / r);
				if (!drag_this) {
					drag_this = true;
					drag++;
				}
			} else {
				targetx = xstart;
				targety = ystart;
				if (drag_this) {
					drag_this = false;
					drag--;
				}
			}
			xpos = xpos * accel + (targetx - x) * convert;
			x += xpos;
			ypos = ypos * accel + (targety - y) * convert;
			y += ypos;
		}
	}
}
 

http://www.weberdesignlabs.com/blog/2009/12/flash-10-coverflow/

---------------------------------------------------------------------------------------------

Thanks to Liip for open sourcing their great coverflow clone, which did very well for
Baltkom TV - Premiere and Cinema channels microsite


We added 2 more features:

• rotation (after last cover first cover is the next)
• startIndex (different start index support)

You can download the patched files or a Subversion patch file

Both features are implemented as settings to be configured in data.xml:

<!-- Turn rotation on by setting rotation to "true": -->
<rotation>true</rotation>


<!-- Display different start conver by specifying start index -->
<startIndex>1</startIndex>


<!-- You can also set this to "center" for having always the middle start index -->
<startIndex>center</startIndex>